LlGetListLength

De DigiWiki.

//Basic usage
default
{
    state_entry()
    {
        list l = ["one", "two", "three"];
        integer i = llGetListLength(l);
        llOwnerSay("there are " + (string)i + " entries in the list");
    }
}

Best Practices

When using list length to help you loop through a list, it is better to determine the length first, then start your loop:

integer i = 0;
integer length = llGetListLength(mylist);
for (; i < length; ++i) {
    llSay(0, llList2String(mylist, i));
}

The following example is to illustrate what not to do, it calculates the length in the "for" loop and is inefficient because the length gets recalculated at each pass through the loop. This should only ever be done if the list is in fact changing (in length) with each iteration of the loop Recalculating the length is slow because the VM duplicates the entire list (including the values) when it is pushed on the stack (so it can be popped off the stack when the length is calculated).

integer i;
for (i = 0; i < llGetListLength(mylist); ++i) {
    llSay(0, llList2String(mylist, i));
}

LSO Optimizations

A faster and lighter (in bytecode) way to determine the length of a list is to do a not-equals compare with a null list. This works because the list not-equals compare returns the difference between the lengths, meaning that it returns the same result as llGetListLength(), minus the overhead in bytecode, and performance penalty of calling a non-native function. Note: This optimization is much less beneficial in Mono. Mono's llGetListLength function is almost twice as fast.

list in;
integer len_in = llGetListLength(in);
integer flen_in = (in != []);
//flen_in and len_in will be the same
 
integer neg_len_in = -llGetListLength(in);
integer fneg_len_in = ([] != in);
//fneg_len_in and neg_len_in will be the same