SHA1

De DigiWiki.

Preforms a SHA-1 Hash on the text. Similar to and MD5 hash, although (slightly) more secure. Two versions of the function are provided, one for UTF-8 Strings (all strings in LSL are UTF-8) and the other is for Base64 Strings (you need to tell it how many bits long the data is).

There is also an SHA-2 implementations (224 & 256).

View Modèle:Wikipedia for more information. 

//////////////////////////////////////////////////////////////////////////////////////
//
//	UTF-8 SHA-1 SHA-160
//	Version 1.2 
//	ESL Compiled: "Dec 13 2010", "01:29:03"
//	Copyright (C) 2010  Strife Onizuka
//	Based on Pseudo-code from http://en.wikipedia.org/wiki/SHA-1
//	https://wiki.secondlife.com/wiki/SHA-1
//
//	This library is free software; you can redistribute it and/or
//	modify it under the terms of the GNU Lesser General Public License
//	as published by the Free Software Foundation;
//	version 3 of the License.
//	
//	This library is distributed in the hope that it will be useful,
//	but WITHOUT ANY WARRANTY; without even the implied warranty of
//	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//	GNU Lesser General Public License for more details.
//	
//	You should have received a copy of the GNU Lesser General Public License
//	along with this library.  If not, see <http://www.gnu.org/licenses/>
//	or write to the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
//	Boston, MA  02111-1307  USA
//	
//////////////////////////////////////////////////////////////////////////////////////
 
//===================================================//
//                 Combined Library                  //
//             "Dec 13 2010", "01:29:03"             //
//  Copyright (C) 2004-2008, Strife Onizuka (cc-by)  //
//    http://creativecommons.org/licenses/by/3.0/    //
//===================================================//
//{
 
string TrimRight(string src, string chrs)//LSLEditor Safe, LSO Safe
{
    integer i = llStringLength(src);
    integer j = i;
    do ; while(~llSubStringIndex(chrs, llGetSubString(src, i = ~-(j = i), i)) && j);
    return llDeleteSubString(src, j, 0x7FFFFFF0);
}
 
string hexc="0123456789ABCDEF";
 
//} Combined Library
 
string Base64_SHA1(string plain, integer bit_length) { //$[E20009]
    integer H1 = 0x67452301;
    integer H2 = 0xefcdab89;
    integer H3 = 0x98badcfe;
    integer H4 = 0x10325476;
    integer H5 = 0xc3d2e1f0;
 
    //OR on the extra bit.
    integer b = ((bit_length + 40) >> 5) | 15;
    integer T = llBase64ToInteger((TrimRight(llGetSubString(plain, -4, -1),"=")) + "AAAA");
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
    if(bit_length)
    {
        i = 0x800000;
        if(!(bit_length % 24))
            i = 0x00000080;
        else if((bit_length % 24) == 16)
            i = 0x00008000;
    }
    else
        T = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,bit_length]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(bit_length << (6 - ((b % 3) << 1)));
    list x;
    integer S = i = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        x = (list)(bit_length = 0);//the zero gets flushed off the stack by the later loops
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = ((i + bit_length) << 4) / 3, T+6)) << (S = ((i + bit_length) % 3) << 1);
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            x += T;
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (D ^ (B & (C ^ D))) + E + 0x5a827999;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(16 > (bit_length = -~bit_length));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (D ^ (B & (C ^ D))) + E + 0x5a827999;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(20 > (bit_length = -~bit_length));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (B ^ C ^ D) + E + 0x6ed9eba1;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(40 > (bit_length = -~bit_length));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + ((B & C) | (B & D) | (C & D)) + E + 0x8f1bbcdc;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(60 > (bit_length = -~bit_length));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)bit_length+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (B ^ C ^ D) + E + 0xca62c1d6;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(80 > (bit_length = -~bit_length));
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5];
    i = -5;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        bit_length = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (bit_length -= 4)) & 0xF), b);
        while (bit_length);
    }while ((i = -~i));
    return buf;
}
 
string UTF8_SHA1(string plain) { 
    integer H1 = 0x67452301;
    integer H2 = 0xefcdab89;
    integer H3 = 0x98badcfe;
    integer H4 = 0x10325476;
    integer H5 = 0xc3d2e1f0;
 
    //OR on the extra bit.
    integer j = llStringLength(plain = llStringToBase64(plain));
    integer T = 0x80000000;
    if (j) {
        do ; while (llGetSubString(plain, (j = ~-j), j) == "=");
        j = (-6 * ~j) & -8;
        T = llBase64ToInteger((llGetSubString(plain, -4, j / 6)) + "AAAAAA") | (0x00000080 << ((j % 3) << 3));
    }
    integer b = ((j + 40) >> 5) | 15;
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T), 0, 5) + 
                            buf, 0, (b << 4) / 3) +
            llIntegerToBase64(j << (6 - ((b % 3) << 1)));
    list x;
    integer S = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        x = (list)(j = 0);//the zero gets flushed off the stack by the later loops
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = ((i + j) << 4) / 3, T+6)) << (S = ((i + j) % 3) << 1);
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (D ^ (B & (C ^ D))) + E + 0x5a827999;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(16 > (j = -~j));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (D ^ (B & (C ^ D))) + E + 0x5a827999;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(20 > (j = -~j));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (B ^ C ^ D) + E + 0x6ed9eba1;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(40 > (j = -~j));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + ((B & C) | (B & D) | (C & D)) + E + 0x8f1bbcdc;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(60 > (j = -~j));
        do
        {
            S = llList2Integer(x,  -3) ^ llList2Integer(x,  -8) ^ llList2Integer(x, -14) ^ llList2Integer(x, -16);
            x = llList2List(x + (T = ((S << 1) | !!(S & 0x80000000))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += ((A << 5) | ((A >> 27) & 0x1F)) + (B ^ C ^ D) + E + 0xca62c1d6;
            E = D;
            D = C;
            C = ((B << 30) | ((B >> 2) & 0x3FFFFFFF));
            B = A;
            A = T;
        }while(80 > (j = -~j));
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5];
    i = -5;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        j = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (j -= 4)) & 0xF), b);
        while (j);
    }while ((i = -~i));
    return buf;
}
 
 
integer go(string in, string answer)
{
    llOwnerSay("");
    llResetTime();
    string out = UTF8_SHA1(in);
    float t = llGetTime();
    llOwnerSay(llDumpList2String(([out,t,llStringLength(in)]),","));
    if(answer)
    {
        llOwnerSay(answer);
        return answer == out;
    }
    return TRUE;
}
 
default
{
    state_entry()
    {
        if (Base64_SHA1("AAAA", 24) != "29e2dcfbb16f63bb0254df7585a15bb6fb5e927d")
            llOwnerSay("Failed Base64_SHA1(\"AAAA\", 24)");
        if(go("", "DA39A3EE5E6B4B0D3255BFEF95601890AFD80709"))
            if(go("abc", "A9993E364706816ABA3E25717850C26C9CD0D89D"))
                if(go("The quick brown fox jumps over the lazy dog", "2FD4E1C67A2D28FCED849EE1BB76E7391B93EB12"))
                    if(go("Étude¿º", llSHA1String("Étude¿º")))
                        go("DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF95601890AFD80709DA39A3EE5E6B4B0D3255BFEF", "");
//        llOwnerSay((string)llGetTime());
    }
}

Preforms a SHA-2 Hash on the text. Similar to and MD5 hash, although (slightly) more secure. Two versions of the function are provided, one for UTF-8 Strings (all strings in LSL are UTF-8) and the other is for Base64 Strings (you need to tell it how many bits long the data is).

SHA-256

//////////////////////////////////////////////////////////////////////////////////////
//
//	UTF-8 SHA-2 SHA-256
//	Version 1.2 
//	ESL Compiled: "Dec 13 2010", "01:29:52"
//	Copyright (C) 2007  Strife Onizuka
//	Based on Pseudo-code from http://en.wikipedia.org/wiki/SHA-2
//	https://wiki.secondlife.com/wiki/SHA-1
//
//	This library is free software; you can redistribute it and/or
//	modify it under the terms of the GNU Lesser General Public License
//	as published by the Free Software Foundation;
//	version 3 of the License.
//	
//	This library is distributed in the hope that it will be useful,
//	but WITHOUT ANY WARRANTY; without even the implied warranty of
//	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//	GNU Lesser General Public License for more details.
//	
//	You should have received a copy of the GNU Lesser General Public License
//	along with this library.  If not, see <http://www.gnu.org/licenses/>
//	or write to the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
//	Boston, MA  02111-1307  USA
//	
//////////////////////////////////////////////////////////////////////////////////////
 
//===================================================//
//                 Combined Library                  //
//             "Dec 13 2010", "01:29:52"             //
//  Copyright (C) 2004-2008, Strife Onizuka (cc-by)  //
//    http://creativecommons.org/licenses/by/3.0/    //
//===================================================//
//{
 
string TrimRight(string src, string chrs)//LSLEditor Safe, LSO Safe
{
    integer i = llStringLength(src);
    integer j = i;
    do ; while(~llSubStringIndex(chrs, llGetSubString(src, i = ~-(j = i), i)) && j);
    return llDeleteSubString(src, j, 0x7FFFFFF0);
}
 
string hexc="0123456789ABCDEF";
 
//} Combined Library
 
list k1 = [ 
    0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
    0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174];
list k2 = [ 
    0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
    0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
    0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
    0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
    0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
    0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2];
 
string UTF8_SHA_256(string plain) { 
    integer H1 = 0x6a09e667;
    integer H2 = 0xbb67ae85;
    integer H3 = 0x3c6ef372;
    integer H4 = 0xa54ff53a;
    integer H5 = 0x510e527f;
    integer H6 = 0x9b05688c;
    integer H7 = 0x1f83d9ab;
    integer H8 = 0x5be0cd19;
 
    //OR on the extra bit.
    integer j = llStringLength(plain = llStringToBase64(plain));
    integer T = 0x80000000;
    if (j) {
        do ; while (llGetSubString(plain, (j = ~-j), j) == "=");
        j = (-6 * ~j) & -8;
        T = llBase64ToInteger((llGetSubString(plain, -4, j / 6)) + "AAAAAA") | (0x00000080 << ((j % 3) << 3));
    }
    integer b = ((j + 40) >> 5) | 15;
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T), 0, 5) + 
                            buf, 0, (b << 5) / 6) + 
            llIntegerToBase64(j << (6 - ((b % 3) << 1)));
    list x;
    integer S = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = (list)(j = 0);//the zero gets flushed off the stack by the later loop
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = (((i + j) << 4) / 3), T + 6)) << (S = (((i + j) % 3) << 1));
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x000007F))) + 
                     (G ^ (E & (F ^ G))) +
                     llList2Integer(k1, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(16 > (j = -~j));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            x = llList2List(x, -16, -1);
            do
            {
                T = llList2Integer(x, -15);
                S = llList2Integer(x, -2);
                x += T = llList2Integer(x,  -16) + 
                         (((T << 25) | ((T >>  7) & 0x01FFFFFF)) ^ 
                          ((T << 14) | ((T >> 18) & 0x00003FFF)) ^ 
                          ((T >> 3) & 0x1FFFFFFF)) + 
                         llList2Integer(x,  -7) + 
                         (((S << 15) | ((S >> 17) & 0x00007FFF)) ^ 
                          ((S << 13) | ((S >> 19) & 0x00001FFF)) ^ 
                          ((S >> 10) & 0x3FFFFF));
//                llOwnerSay("W["+(string)j+"]="+hex(T));
                T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                          ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                          ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                         ((E & F) ^ ((~E) & G)) +
                         llList2Integer(k2, j - 16);
                H = G;
                G = F;
                F = E;
                E = D + T;
                D = C;
                C = B;
                B = A;
                A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                         ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                         ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                        ((B & C) ^ (B & D) ^ (C & D));
            }while(3 & (j = -~j));
        }while(64 > j);
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        j = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (j -= 4)) & 0xF), b);
        while (j);
    }while ((i = -~i));
    return buf;
}
 
string Base64_SHA_256(string plain, integer bit_length) { //$[E20009]
    integer H1 = 0x6a09e667;
    integer H2 = 0xbb67ae85;
    integer H3 = 0x3c6ef372;
    integer H4 = 0xa54ff53a;
    integer H5 = 0x510e527f;
    integer H6 = 0x9b05688c;
    integer H7 = 0x1f83d9ab;
    integer H8 = 0x5be0cd19;
 
    //OR on the extra bit.
    integer b = (~-(((bit_length + 552) & -512) >> 5));
    integer T = llBase64ToInteger(TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")+"AAAA");
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
    if(bit_length)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(bit_length << (6 - ((b % 3) << 1)));
    list x;
    integer S = i = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = (list)(bit_length = 0);//the zero gets flushed off the stack by the later loop
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = (((i + bit_length) << 4) / 3), T+6)) << (S = (((i + bit_length) % 3) << 1));
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                     ((E & F) ^ ((~E) & G)) + 
                     llList2Integer(k1, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(16 > (bit_length = -~bit_length));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            x = llList2List(x, -16, -1);
            do
            {
                T = llList2Integer(x, -15);
                S = llList2Integer(x, -2);
                x += T = llList2Integer(x,  -16) + 
                         (((T << 25) | ((T >>  7) & 0x01FFFFFF)) ^ 
                          ((T << 14) | ((T >> 18) & 0x00003FFF)) ^ 
                          ((T >> 3) & 0x1FFFFFFF)) + 
                         llList2Integer(x,  -7) + 
                         (((S << 15) | ((S >> 17) & 0x00007FFF)) ^ 
                          ((S << 13) | ((S >> 19) & 0x00001FFF)) ^ 
                          ((S >> 10) & 0x3FFFFF));
    //            llOwnerSay("W["+(string)j+"]="+hex(T));
                T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                          ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                          ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                         ((E & F) ^ ((~E) & G)) +
                         llList2Integer(k2, bit_length - 16);
                H = G;
                G = F;
                F = E;
                E = D + T;
                D = C;
                C = B;
                B = A;
                A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                         ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                         ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                        ((B & C) ^ (B & D) ^ (C & D));
            }while(3 & (bit_length = -~bit_length));
        }while(64 > bit_length);
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        bit_length = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (bit_length -= 4)) & 0xF), b);
        while (bit_length);
    }while ((i = -~i));
    return buf;
}
 
integer go(string in, string answer)
{
    llOwnerSay("");
    llResetTime();
    string out = UTF8_SHA_256(in);
    float t = llGetTime();
    llOwnerSay(llList2CSV(([out,t,llStringLength(in)])));
    if(answer)
    {
        llOwnerSay(answer);
        return answer == out;
    }
    return TRUE;
}
 
default
{
    state_entry()
    {
        if(go("","E3B0C44298FC1C149AFBF4C8996FB92427AE41E4649B934CA495991B7852B855"))
            if(go("abc","BA7816BF8F01CFEA414140DE5DAE2223B00361A396177A9CB410FF61F20015AD"))
                if(go("The quick brown fox jumps over the lazy dog","D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592"))
                    go("D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592","");
//        llOwnerSay((string)llGetTime());
    }
}

SHA-224

//////////////////////////////////////////////////////////////////////////////////////
//
//	UTF-8 SHA-2 SHA-224
//	Version 1.2 
//	ESL Compiled: "Dec 13 2010", "01:34:46"
//	Copyright (C) 2010  Strife Onizuka
//	Based on Pseudo-code from http://en.wikipedia.org/wiki/SHA-2
//	https://wiki.secondlife.com/wiki/SHA-1
//
//	This library is free software; you can redistribute it and/or
//	modify it under the terms of the GNU Lesser General Public License
//	as published by the Free Software Foundation;
//	version 3 of the License.
//	
//	This library is distributed in the hope that it will be useful,
//	but WITHOUT ANY WARRANTY; without even the implied warranty of
//	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//	GNU Lesser General Public License for more details.
//	
//	You should have received a copy of the GNU Lesser General Public License
//	along with this library.  If not, see <http://www.gnu.org/licenses/>
//	or write to the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
//	Boston, MA  02111-1307  USA
//	
//////////////////////////////////////////////////////////////////////////////////////
 
//===================================================//
//                 Combined Library                  //
//             "Dec 13 2010", "01:34:46"             //
//  Copyright (C) 2004-2008, Strife Onizuka (cc-by)  //
//    http://creativecommons.org/licenses/by/3.0/    //
//===================================================//
//{
 
string TrimRight(string src, string chrs)//LSLEditor Safe, LSO Safe
{
    integer i = llStringLength(src);
    integer j = i;
    do ; while(~llSubStringIndex(chrs, llGetSubString(src, i = ~-(j = i), i)) && j);
    return llDeleteSubString(src, j, 0x7FFFFFF0);
}
 
string hexc="0123456789ABCDEF";
 
//} Combined Library
 
list k1 = [ 
    0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
    0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174];
list k2 = [ 
    0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
    0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
    0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
    0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
    0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
    0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2];
 
string UTF8_SHA_224(string plain) {
    integer H1 = 0xC1059ED8;
    integer H2 = 0x367CD507;
    integer H3 = 0x3070DD17;
    integer H4 = 0xF70E5939;
    integer H5 = 0xFFC00B31;
    integer H6 = 0x68581511;
    integer H7 = 0x64F98FA7;
    integer H8 = 0xBEFA4FA4;
 
    //OR on the extra bit.
    integer j = llStringLength(plain = llStringToBase64(plain));
    integer T = 0x80000000;
    if (j) {
        do ; while (llGetSubString(plain, (j = ~-j), j) == "=");
        j = (-6 * ~j) & -8;
        T = llBase64ToInteger((llGetSubString(plain, -4, j / 6)) + "AAAAAA") | (0x00000080 << ((j % 3) << 3));
    }
    integer b = ((j + 40) >> 5) | 15;
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T), 0, 5) + 
                            buf, 0, (b << 5) / 6) + 
            llIntegerToBase64(j << (6 - ((b % 3) << 1)));
    list x;
    integer S = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = (list)(j = 0);//the zero gets flushed off the stack by the later loop
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = ((i + j) << 4) / 3, 6+T)) << (S = (((i + j) % 3) << 1));
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k1, j);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(16 > (j = -~j));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + (T = (llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x01FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x00003FFF)) ^ 
                                     ((T >>  3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x00007FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x00001FFF)) ^ 
                                     ((S >> 10) & 0x003FFFFF)))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k2, j - 16);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(64 > (j = -~j));
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5, H6, H7];//, H8];
    i = -7;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        j = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (j -= 4)) & 0xF), b);
        while (j);
    }while ((i = -~i));
    return buf;
}
 
string Base64_SHA_224(string plain, integer bit_length) { //$[E20009]
    integer H1 = 0xC1059ED8;
    integer H2 = 0x367CD507;
    integer H3 = 0x3070DD17;
    integer H4 = 0xF70E5939;
    integer H5 = 0xFFC00B31;
    integer H6 = 0x68581511;
    integer H7 = 0x64F98FA7;
    integer H8 = 0xBEFA4FA4;
 
    //OR on the extra bit.
    integer b = (~-(((bit_length + 552) & -512) >> 5));
    integer T = llBase64ToInteger((TrimRight(llGetSubString(plain = llStringToBase64(plain), -4, -1),"=")) + "AAAA");
    string buf = "AAA";
    integer i = -5;
    do buf += buf; while((i = -~i));
    if(bit_length)
    {
        i = 0x800000;
        if(T & 0xFF00)
            i = 0x00000080;
        else if(T & 0xFF0000)
            i = 0x00008000;
    }
    else
        T = 0x80000000;//T is corrupt because of https://jira.secondlife.com/browse/SVC-104
//    llOwnerSay(llList2CSV([i,j]));
    plain = llGetSubString( llDeleteSubString(plain, -4, -1) + 
                            llGetSubString(llIntegerToBase64(T | i), 0, 5) + 
                            buf, 0, (b << 4) / 3) + 
            llIntegerToBase64(bit_length << (6 - ((b % 3) << 1)));
    list x;
    integer S = i = 0;
    do
    {
        integer A = H1;
        integer B = H2;
        integer C = H3;
        integer D = H4;
        integer E = H5;
        integer F = H6;
        integer G = H7;
        integer H = H8;
        x = (list)(bit_length = 0);//the zero gets flushed off the stack by the later loop
        do
        {
            T = llBase64ToInteger(buf = llGetSubString(plain, T = ((i + bit_length) << 4) / 3, 6+T)) << (S = (((i + bit_length) % 3) << 1));
            if(S)
                T = T | (llBase64ToInteger("A" + (llDeleteSubString(buf, 0, 1))) >> (6 - S));
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            x += T;
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k1, bit_length);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(16 > (bit_length = -~bit_length));
//		llOwnerSay(llList2CSV(hexm(x)));
        do
        {
            T = llList2Integer(x, -15);
            S = llList2Integer(x, -2);
            x = llList2List(x + (T = (llList2Integer(x,  -16) + 
                                    (((T << 25) | ((T >>  7) & 0x01FFFFFF)) ^ 
                                     ((T << 14) | ((T >> 18) & 0x00003FFF)) ^ 
                                     ((T >>  3) & 0x1FFFFFFF)) + 
                                    llList2Integer(x,  -7) + 
                                    (((S << 15) | ((S >> 17) & 0x00007FFF)) ^ 
                                     ((S << 13) | ((S >> 19) & 0x00001FFF)) ^ 
                                     ((S >> 10) & 0x003FFFFF)))), -16, -1);
//            llOwnerSay("W["+(string)j+"]="+hex(T));
            T += H + (((E << 26) | ((E >>  6) & 0x03FFFFFF)) ^ 
                      ((E << 21) | ((E >> 11) & 0x001FFFFF)) ^ 
                      ((E <<  7) | ((E >> 25) & 0x0000007F))) + 
                     ((E & F) ^ ((~E) & G)) + llList2Integer(k2, bit_length - 16);
            H = G;
            G = F;
            F = E;
            E = D + T;
            D = C;
            C = B;
            B = A;
            A = T + (((B << 30) | ((B >>  2) & 0x3FFFFFFF)) ^ 
                     ((B << 19) | ((B >> 13) & 0x0007FFFF)) ^ 
                     ((B << 10) | ((B >> 22) & 0x000003FF))) + 
                    ((B & C) ^ (B & D) ^ (C & D));
        }while(64 > (bit_length = -~bit_length));
        H1 += A;
        H2 += B;
        H3 += C;
        H4 += D;
        H5 += E;
        H6 += F;
        H7 += G;
        H8 += H;
    }while(b > (i += 16));
    x = [H1, H2, H3, H4, H5, H6, H7, H8];
    i = -8;
    buf = "";
    do
    {
        T = llList2Integer(x,i);
        bit_length = 32;
        do
            buf += llGetSubString(hexc, b = ((T >> (bit_length -= 4)) & 0xF), b);
        while (bit_length);
    }while ((i = -~i));
    return buf;
}
 
integer go(string in, string answer)
{
    llOwnerSay("");
    llResetTime();
    string out = UTF8_SHA_224(in);
    float t = llGetTime();
    llOwnerSay(llList2CSV([out,t,llStringLength(in)]));
    if(answer)
    {
        llOwnerSay(answer);
        return answer == out;
    }
    return TRUE;
}
 
default
{
    state_entry()
    {
        if(go("","D14A028C2A3A2BC9476102BB288234C415A2B01F828EA62AC5B3E42F"))
            if(go("abc","23097D223405D8228642A477BDA255B32AADBCE4BDA0B3F7E36C9DA7"))
                if(go("The quick brown fox jumps over the lazy dog","730E109BD7A8A32B1CB9D9A09AA2325D2430587DDBC0C38BAD911525"))
                    go("D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592D7A8FBB307D7809469CA9ABCB0082E4F8D5651E46D3CDB762D02D0BF37C9E592","");
//        llOwnerSay((string)llGetTime());
    }
}
Récupérée de « http://digigrids.free.fr/wiki/index.php?title=SHA1 »
Outils personnels
  • Cette page a été consultée 1 141 fois.
donate
Google Ads